/////////////////////////////////////////////////////////////////////
// "On the torsion of rational elliptic curves over sextic fields" //
//        Harris B. Daniels and Enrique González-Jiménez           //
/////////////////////////////////////////////////////////////////////

// 2/8/2018 - Magma 2.23

// Magma script related to Proposition 8 (s) 


//f1 is the j-map from X_0(7) to P1 taken from Zywina, On the possible images of the 
//mod l representations associated to elliptic curves over Q.
//f2 is the j-map from X_{20} to P1 taken from Rouse, Zureick-Brown, Elliptic curves 
//over $\Q$ and $2$-adic images of Galois.

F<t> := FunctionField(Rationals());
f1 := (t^2+13*t+49)*(t^2+5*t+1)^3*t^-1;
f2 := (-4*t^8 + 32*t^7 + 80*t^6 - 288*t^5 - 504*t^4 + 864*t^3 + 1296*t^2 - 864*t - 1188)/(t^4 + 4*t^3 + 6*t^2 + 4*t + 1);
R<x,y>:=PolynomialRing(Rationals(),2);
g:=Numerator(Evaluate(f1,x)-Evaluate(f2,y));
assert IsIrreducible(g);
C<X,Y,Z>:=ProjectiveClosure(Curve(AffineSpace(R),g));
Genus(C);
_,H,map := IsHyperelliptic(C);

G1, m1 := AutomorphismGroup(H);
phi := m1(G1.3);
G := AutomorphismGroup(H,[phi]);
QC, pi := CurveQuotient(G);
pts := Points(QC : Bound :=100);
E, m2 := EllipticCurve(QC,pts[1]);
assert CremonaReference(E) eq "14a4";
assert Rank(E) eq 0;
PTS :=Points(E: Bound:=8000);
assert #PTS eq #TorsionSubgroup(E);

Set := [];
PHI := map *pi*m2;
for p in PTS do
assert RationalPoints(p @@ PHI) subset {@ C![-49/4 , -17/16 , 1], C![-4 , 3 , 1], C![-49/4 , 31 , 1], C![-4 , -3/2 , 1], C![0 , -1 , 1], C![0 , 1 , 0], C![1 , 0 , 0] @};
end for;

/*
Thus there are 2 non-sinqular points ( [-49/4 , -17/16 , 1], [-49/4 , 31 , 1], [-4 , 3 , 1], [-4 , -3/2 , 1] ), 1 singular point ( [0,-1,1] )and two cusps at infinity ( [0,1,0], [1,0,0] )
*/


assert Evaluate(f1,-49/4) eq Evaluate(f2,-17/16);
assert Evaluate(f1,-49/4) eq Evaluate(f2,31);
assert Evaluate(f1,-4) eq Evaluate(f2,3);
assert Evaluate(f1,-4) eq Evaluate(f2,-3/2);

assert [Evaluate(f1,-49/4), Evaluate(f1,-4)] eq [ -38575685889/16384, 351/4 ];
    

//At and Bt give the elliptic model for E_{7,1} from Zywina, On the possible images 
//of the mod l representations associated to elliptic curves over Q Section 1.4. 
//These curves have G_E(7) equal to 7B.2.3 according to Zywina Theorem 1.5.
At := -27*(t^2+13*t+49)^3*(t^2+245*t+2401);
Bt := 54*(t^2+13*t+49)^4*(t^4-490*t^3-21609*t^2-235298*t-823543);

A1 := Evaluate(At, -49/4);
B1 := Evaluate(Bt, -49/4);

A2 := Evaluate(At, -4);
B2 := Evaluate(Bt, -4);


//We twist by -7 so these elliptic curves have mod G_E(7) equal to 7B.2.1 according 
//to Zywina Theorem 1.5,
E1 := QuadraticTwist(EllipticCurve([A1,B1]),-7);
E2 := QuadraticTwist(EllipticCurve([A2,B2]),-7);

assert CremonaReference(E1) eq "338b1";
assert CremonaReference(E2) eq "16562be2";